Plugin: External Apps

[JREkiwi]

A UI mod plugin that provides a button on the Video Options menu that can be used to run any external application, using the current video filename (among other things) as an argument.

This is a port of the V6 version which had a discussion here.

Options in Setup -> Detailed Setup -> Customize -> External App Options
Specify the External App directory where your batch/exe files are.
In each "slot" you can specify a Name, the batch/exe file you want to run, whether it should be available while a video is still recording or whether an xml file for the video needs to exist. And what Sage should do when you run the app, Sleep, Wait, Exit or have the app run in the Background.

Parameters passed to the batch file are:
%1 = MediaFile
%2 = Title
%3 = Episode
%4 = Description
%5 = Channel Number
%6 = Duration
%7 = Date
%8 = Category
%9 = SubCategory

Most success if achieved by using a trigger batch file which calls the functional batch file to actually do the processing. For example.

External Apps calls Compressit.cmd which contains

@echo off
C:
cd "C:\Program Files\SageTV\SageTV\Compressor"
start "Compress" /MIN /LOW /WAIT compress.cmd %1 %2 %3 %4 %5 %6 %7 %8 %9

and C:\Program Files\SageTV\SageTV\Compressor\compress.cmd contains

mencoder %1 -edl %~dpn1.edl -oac copy -ovc copy -of mpeg -o E:\\Archived\\%~n1.avi
exit

John

[dinki]

I'd like to use this to run an external command (batch file that sends a command to my Home Automation server to turn on/off lights in the living room) similar to the way I did using SageMC external command. Is there any way to tie this to an IR button?

[skyeclad]

Nice plugin! Saves me from having to diagnose VC-1/SageTV playback issues. I'll just run them in PDVD9 instead.

Any way to use this plugin to run an external app on BD ISO files? I would imagine that you would need something to mount the file first which Sage does but I don't know how to tell the next app where to look for the new BD mounted drive.

[peternm22]

I can't seem to get this to work on a batch file I want to run. I tried running running it from an HD100 and locally on the SageTV server, but the batch file never completes its actions. I'm running SageTV as a service, if that makes a difference.

I'm trying to use it to run a batch file that triggers VideoReDo's Quickstream Fix, but I can't get it to work. Here is the batch file that I am trying to run:

IF EXIST "%~d1%~p1%~n1.working" goto end
dir "%~f1">>"%~d1%~p1%~n1.working"
IF EXIST "%~d1%~p1%~n1.QFixed" goto end
IF EXIST "%~d1%~p1%~n1.compressed" goto end
del "%~d1%~p1tmpEncode\%~n1.tmp"

set extension=mpg
set usetouch=no

set touchpath=D:\Sage\QFixSage\
set videoredo_path=C:\Program Files (x86)\VideoReDoTVSuite\

set priority=low

set delOriginal=yes

rem "set delOriginal above to yes or no.... yes will delete original mpg and replace with QFixed file."
rem "if set to no will QFix file to tmpEncode directory but will not delete original...."

rem ........Do Not Touch Below................................................
Title QFixxing %1
if Not exist "%~f1" exit
if NOT exist "%videoredo_path%vp.vbs" goto :errorvrd
if /I "%usetouch%" EQU "yes" if Not exist "%touchpath%touch.exe" goto errtouch

md "%~d1%~p1tmpEncode"

START /B /W /MIN /%priority% cscript.exe //nologo "%videoredo_path%vp.vbs" "%~f1" "%~d1%~p1tmpEncode\%~n1.tmp" /t1 /d /q
if errorlevel = 1 goto end
if /I "%usetouch%" EQU "yes" if exist "%~d1%~p1tmpEncode\%~n1.tmp" "%touchpath%touch.exe" -r "%~f1" "%~d1%~p1tmpEncode\%~n1.tmp"
if /I "%usetouch%" EQU "yes" if errorlevel = 1 goto :errtouch
if /I "%delOriginal%" EQU "yes" if exist "%~d1%~p1tmpEncode\%~n1.tmp" del "%~f1"
if /I "%delOriginal%" EQU "yes" if not exist "%~f1" echo "Qfix Completed">>"%~d1%~p1%~n1.QFixed"
if /I "%delOriginal%" EQU "yes" if not exist "%~d1%~p1%~n1.QFixed" if exist "%~f1" echo "File In Use Not Replaced">>"%~d1%~p1%~n1.inuse%extension%"
if /I "%delOriginal%" EQU "yes" if exist "%~d1%~p1%~n1.QFixed" if not exist "%~f1" move "%~d1%~p1tmpEncode\%~n1.tmp" "%~d1%~p1%~n1.%extension%"
del "%~d1%~p1%~n1.working"
:end
exit
:errorvrd
echo "Videoredo not found in %videoredo_path%" >>"%~d1%~p1%~n1.error"
exit
:errtouch
echo "Error Touch.exe not found in %touchpath%" >>"%~d1%~p1%~n1.error"
exit

When I run the batch file from the External Apps, the .working file is created (which means the batch file is being run), but VideoReDO never starts.

Any ideas?

[gplasky]

Your videoredo path has a space in it. It might require quotes around the path.

Gerry

[peternm22]

Tried it with quotes around the path, nothing changes.

I should note that the batch file works perfectly when run normally (when not called from Sage).

[peternm22]

Alright, I've made a little bit of progress but I'm still a bit stumped.

I reduced the batch file until I could make in runnable within Sage. The original batch file was created by someone else on the forum, so I never fully knew how it worked.

I can now successfully run the VideoReDo quickstream fix, but I'm having trouble getting the fixed file to replace the original. When I run the quickstream fix, I have the file temporally placed in a folder called "tmpEncode". Once VideoReDo is done being run, I want to delete the original file (which has a .ts file extension) and move the fixed file (which has a .mpg file extension) into its place. The batch file as it is now:

START /B /W /MIN /low cscript.exe //nologo "C:\Program Files (x86)\VideoReDoTVSuite\vp.vbs" "%~f1" "%~d1%~p1tmpEncode\%~n1.tmp" /t1 /d /q

del "%~f1"
move "%~d1%~p1tmpEncode\%~n1.tmp" "%~d1%~p1%~n1.mpg"

The problem with the above file is that it will delete the original file, but it never executes the "move" command on the second line. I decided to reverse the delete/move:

START /B /W /MIN /low cscript.exe //nologo "C:\Program Files (x86)\VideoReDoTVSuite\vp.vbs" "%~f1" "%~d1%~p1tmpEncode\%~n1.tmp" /t1 /d /q

move "%~d1%~p1tmpEncode\%~n1.tmp" "%~d1%~p1%~n1.mpg"
del "%~f1"

And this moves the fixed file into the correct position, but never deletes the original. Weird huh? It will execute the first command, but not the second.

Again, this batch file works perfectly when run within Windows. But it has issues when running from Sage.

I've been trying to get this running for well over a year now (you can see my previous postings on the forum with my failed attempts), but I seem to be really close to getting it to work this time. If anyone has any suggestions, I would be really appreciative.

Thanks.

[JREkiwi]

As you are running as a service you don't get any paths set so you will need a full path specified for cscript.exe.

C:\WINDOWS\system32\cscript.exe or whatever the path is.

Should there be a colon in goto :errorvrd ?

John

[nyplayer]

Originally Posted by peternm22

Alright, I've made a little bit of progress but I'm still a bit stumped.

I reduced the batch file until I could make in runnable within Sage. The original batch file was created by someone else on the forum, so I never fully knew how it worked.

I can now successfully run the VideoReDo quickstream fix, but I'm having trouble getting the fixed file to replace the original. When I run the quickstream fix, I have the file temporally placed in a folder called "tmpEncode". Once VideoReDo is done being run, I want to delete the original file (which has a .ts file extension) and move the fixed file (which has a .mpg file extension) into its place. The batch file as it is now:

START /B /W /MIN /low cscript.exe //nologo "C:\Program Files (x86)\VideoReDoTVSuite\vp.vbs" "%~f1" "%~d1%~p1tmpEncode\%~n1.tmp" /t1 /d /q

del "%~f1"
move "%~d1%~p1tmpEncode\%~n1.tmp" "%~d1%~p1%~n1.mpg"

The problem with the above file is that it will delete the original file, but it never executes the "move" command on the second line. I decided to reverse the delete/move:

START /B /W /MIN /low cscript.exe //nologo "C:\Program Files (x86)\VideoReDoTVSuite\vp.vbs" "%~f1" "%~d1%~p1tmpEncode\%~n1.tmp" /t1 /d /q

move "%~d1%~p1tmpEncode\%~n1.tmp" "%~d1%~p1%~n1.mpg"
del "%~f1"

And this moves the fixed file into the correct position, but never deletes the original. Weird huh? It will execute the first command, but not the second.

Again, this batch file works perfectly when run within Windows. But it has issues when running from Sage.

I've been trying to get this running for well over a year now (you can see my previous postings on the forum with my failed attempts), but I seem to be really close to getting it to work this time. If anyone has any suggestions, I would be really appreciative.

Thanks.

The problem might be the path... you probably need to set the path in the batchfile to find the system commands. Add the below to the top of the batchfile and try it. if your windows paths are different for ex c:\winnt then make the changes.


set PATH=C:\;C:\windows;C:\WINDOWS\system32

[peternm22]

Originally Posted by nyplayer

The problem might be the path... you probably need to set the path in the batchfile to find the system commands.

Thanks for the idea, but it still doesn't work. I don't think it is having trouble finding the system commands though, since it DOES execute the command I put first (the move or the delete), but it simply ignores the second command. If it was having trouble with the system commands, shouldn't they all fail regardless of where they are in the batch file?

Any other thoughts?

[peternm22]

Originally Posted by JREkiwi

As you are running as a service you don't get any paths set so you will need a full path specified for cscript.exe.

C:\WINDOWS\system32\cscript.exe or whatever the path is.

Should there be a colon in goto :errorvrd ?

John

Hi John,

I've managed to get VideoReDo running fine (which uses the cscript.exe program). It's what comes AFTER that isn't working now (moving/deleting the files).

Thanks. (awesome plugin BTW)

[JREkiwi]

Try

move "%~d1%~p1tmpEncode\%~n1.tmp" "%~d1%~p1%~n1.mpg" >> c:\log.txt
del "%~f1" >> c:\log.txt

and see you you get anything logged.

John

[nyplayer]

peternm22,

Try what John suggested if that doesn't' work try using the call command

START /B /W /MIN /low cscript.exe //nologo "C:\Program Files (x86)\VideoReDoTVSuite\vp.vbs" "%~f1" "%~d1%~p1tmpEncode\%~n1.tmp" /t1 /d /q

call move "%~d1%~p1tmpEncode\%~n1.tmp" "%~d1%~p1%~n1.mpg"
del "%~f1"

[peternm22]

John,

If I do the delete command first, the file log.txt is blank. (the file is deleted though). If I do the move command first, the log.txt file contains: "1 file(s) moved.", but the other file isn't deleted.


nyplayer,

Using the "call" command doesn't change anything. The first command is executed (whether it is the move or the delete), but the second command never happens. I tried a few different combination's of the "call" command (on both the move/delete, and just one, etc). No effect whatsoever.

This seems quite odd to me. It's not as if the move and delete commands are conflicting with each other, since they are being used on different files.

[peternm22]

More testing.... I thought that maybe since the script was using 2 different directories (the recordings, and tmpEncode), it might be getting confused which directly to write to. Long shot, I know.

So I decided to log the paths to text files after each command. Giving me this needlessly complex code:

START /B /W /MIN /low cscript.exe //nologo "C:\Program Files (x86)\VideoReDoTVSuite\vp.vbs" "%~f1" "%~d1%~p1tmpEncode\%~n1.tmp" /t1 /d /q

echo "%~d1%~p1tmpEncode\%~n1.tmp" >> c:\move1.txt
echo "%~f1" >> c:\del1.txt

move "%~d1%~p1tmpEncode\%~n1.tmp" "%~d1%~p1%~n1.mpg"

echo "%~d1%~p1tmpEncode\%~n1.tmp" >> c:\move2.txt
echo "%~f1" >> c:\del2.txt

del "%~f1"

echo "%~d1%~p1tmpEncode\%~n1.tmp" >> c:\move3.txt
echo "%~d1%~p1tmpEncode\%~n1.tmp" >> c:\move3.txt

So I run it, and it only creates the first text file (move1.txt). None of the other text files are created, and the "move" command is never executed either (despite being before the delete command).

It would appear that I can only execute batch files with 2 lines of commands in Sage. Everything after that is ignored. This seems to explain why the original batch file never ran properly (it would create a .working file, but nothing after that).

This seems to slightly narrow down the problem, but I don't know how to fix it or why it is happening. Thoughts?

[peternm22]

I ran a test, writing 5 different text files via a batch file from Sage. It worked perfectly. I put the call to VideoReDo at the top of the file, and it only writes the first text file.

So, this means there is a problem with this line, causing problems later on:

START /B /W /MIN /low cscript.exe //nologo "C:\Program Files (x86)\VideoReDoTVSuite\vp.vbs" "%~f1" "%~d1%~p1tmpEncode\%~n1.tmp" /t1 /d /q

I tried putting the full path in to cscript.exe, but I must have done it wrong since VideoReDo doesn't run:

START /B /W /MIN /low C:\WINDOWS\system32\cscript.exe //nologo "C:\Program Files (x86)\VideoReDoTVSuite\vp.vbs" "%~f1" "%~d1%~p1tmpEncode\%~n1.tmp" /t1 /d /q

Getting closer...

[JREkiwi]

How about trying it without the Start and use Batch mode for cscript.exe

cscript.exe //B "C:\Program Files (x86)\VideoReDoTVSuite\vp.vbs" "%~f1" "%~d1%~p1tmpEncode\%~n1.tmp" /t1 /d /q

John

[nyplayer]

Peter and John,

For some reason qfixsage does not work with the external apps .... but it does work if you use a trigger job. Peter you can use the code below and just put in the correct path to your qfix. You can then have John's external apllication trigger it. I tested and it does work.

StartQfixSage.bat

if not exist c:\temp md c:\temp
c:\work\qfixsage.bat %1>c:\temp\logvrd.txt

PS Peter i was the one that had originally wrote that batch file. I will have to look further to see why it doesn't work without a trigger job.


John it appears for some reason your are not passing the file name by default? and the Qfix job does not use %1.

[peternm22]

Originally Posted by nyplayer

Peter and John,
For some reason qfixsage does not work with the external apps .... but it does work if you use a trigger job. Peter you can use the code below and just put in the correct path to your qfix. You can then have John's external apllication trigger it. I tested and it does work.

Is a "trigger" job simply one batch file calling another batch file? I'll try it out when I get home, see if it does the trick.

Originally Posted by nyplayer

PS Peter i was the one that had originally wrote that batch file.

I thought I recognized your name The script has come in VERY handy since I've been using a R5000. If I can get your original batch file running, that would be ideal over what I have cobbled together. You seem to have put a few safety checks in your batch file so I don't accidentally delete a recording if the QFix doesn't work.

[nyplayer]

Originally Posted by peternm22

Is a "trigger" job simply one batch file calling another batch file? I'll try it out when I get home, see if it does the trick.



I thought I recognized your name The script has come in VERY handy since I've been using a R5000. If I can get your original batch file running, that would be ideal over what I have cobbled together. You seem to have put a few safety checks in your batch file so I don't accidentally delete a recording if the QFix doesn't work.

Yes a trigger is one batch calling another.

I believe the problem is that the filename is not passed by default to QFIXSAGE and no where in QFIXSAGE is %1 to select the file name.